Excel Thoughts

Using Dropbox to Sync files online and across different computers

2009-09-21T13:11:00.000+09:30

I recently lost a couple of hard drives in a storm and lost a lot of data. So, I went looking for an easy online backup solution. I looked at a few options and started using Dropbox recently.

From Dropbox's website:

You can sync up to 100GB of your files online and across different computers.
Sync files of any size or type
Share large files and photos easily
Automatic online backup
Track and undo changes to files

They give you 2GB storage for free so why not give it a try?

Click the Dropbox link on the right hand side of this blog to go straight to their site.

C# version of VB6/VBA's Val function

2008-07-10T09:32:00.004+09:30

Here is some code to emulate VB6/VBA's Val function in C#. I found the original http://www.dreamincode.net/code/snippet1821.htm but it needed some changes to work correctly.

using System.Text.RegularExpressions;

using System;

namespace ValinCS

{

class Program

{

static void Main(string[] args)

{

Console.WriteLine(Val("AAA234"));

Console.WriteLine(Val("1234asdv"));

Console.WriteLine(Val(" 345"));

Console.WriteLine(Val("1.2345f"));

Console.WriteLine(Val(" 1 2"));

Console.WriteLine(Val(""));

Console.WriteLine(Val("12"));

}

private static int Val(string value)

{

string returnVal = string.Empty;

int tryInt = 0;

//^ specifies that the match has to start at the start of the string

//Trim() trims both ends of the string before matching

MatchCollection collection = Regex.Matches(value.Trim(), "^\\d+");

foreach (Match match in collection)

{

returnVal += match.ToString();

}

//attempt conversion to int

int.TryParse(returnVal,out tryInt);

return tryInt;

}

}

}

Cloning using Serialization

2008-07-02T21:58:00.004+09:30

I found some great C# code the other day which allows deep copying of objects, rather than shallow copies which object.Clone() does. Saved heaps of time mucking around with the ICloneable interface, and basically rewriting heaps of code.

You need to decorate the class(es) that you want to clone with the [Serializable] attribute. If you are trying to clone a object of a type which has members of some other class, those classes need to be serializable too.

public static object Clone(object obj)
{
MemoryStream ms = new MemoryStream();
BinaryFormatter bf = new BinaryFormatter();
bf.Serialize(ms, obj);
ms.Flush();
ms.Seek(0, SeekOrigin.Begin);
return bf.Deserialize(ms);
}

Ebay International Search Gadget rewritten

2008-07-02T15:33:00.006+09:30

For any of you that use the Ebay international search gadget on the right hand side of the blog, I have just rewritten it as it was not working anymore.

I am have also added an Amazon international search gadget.

Use them directly from this site or add them to your iGoogle page. Note that the international functionadoes not work if you use the gadgets directly from this site. It only links to the respective US sites. You need to add it to a your iGoogle page to get the full functionality.

Creating Excel/Office 2007 Addins in Visual Studio 2008

2008-05-06T13:14:00.004+09:30

A month or 2 ago I went to the Heroes launch of VS 2008 in Adelaide. There are some exciting things happening in VS2008, especially with the Shared Addin in VS2008. Previously, you needed to go through the mess of creating a Shim, and manually creating XML to write to a ribbon. Now, they have made it simple. There is a Ribbon control to add which creates all the XML in the background, and all the shimming stuff happens automatically.

Create a New Project

Adding a Ribbon Control

Adding Controls from the Toolbox to the Ribbon

Finally!!! It is easy.

Apologies...

2007-09-07T14:29:00.000+09:30

Apologies to all who visit here of late. The server I use has been taken offline, and I am in the process of moving all files to a new server. All images and downloadable files are currently missing.

And when I have time, I will share some Excel/C# porting experiences.

Using Images in CommandBarButtons

2007-01-09T10:30:00.000+10:30

A reader asked me whether he could add any image to a Word or Excel toolbar button without using any VBA. I have put together a couple of screenshots from Word, but they are virtually identical in Excel (pre Office 2007). Office 2007 has a Ribbon instead, so that post will come later.

Image 1

If you right click on the Toolbar area in word or Excel, you can customise (forgive the Australian spelling with an 's'!) the way the Toolbar looks. (see Image 1) . Click "Customize" at the bottom of this context menu.

Image 2

This will display the "Customize" menu (Image 2). To add your own button, select the Commands tab, and select "Macros" from the list. If there is nothing in the right window (Normal.NewMacros.Macro1 is in the right window in this example), you need to record a macro using the Macro Recorder.

Image 3

Now, drag this macro from the right window onto the Toolbar where you want it. The I Beam cursor is displayed to indicate where the new button will be displayed. (Image 3)

Image 4

When you let go of the mouse the button is displayed (Image 4)

Image 5

To rename the Button, change the text in the Name section. To show your image, copy an image from somewhere on your computer to the clipboard, and click "Paste Button Image". Click Image and Text to display your image. (Image 5)

Name Manager in Excel 2007

2006-12-30T08:59:00.000+10:30

I thought I would do a series on some of the features in Excel 2007.

One of the annoying things in old Excel was the maintenance of Names. Excel 2007 has made it a lot nicer with the Name Manager.

Here is a part of the Formulas tab with the Name Manager highlighted.

Click this and the following is displayed. You can see clearly which name is a Workbook scope and which is a Worksheet scope.

Click New to add a new name... In the Scope section, you have the choice of Workbook or the individual sheets in the Workbook. Easy!

Also you can use Name a Range to highlight a range and then apply a name to it or Apply Names to apply an existing name to a highlighted range.

If you wish to add a formula with a name in it, choose Use In Formula.

One last thing possible is for Excel to automatically create names based on the content on the cells using Create From Selection. Highlight a desired section, and Excel gives you options for which part of the selection you would like the Name to be created from. In this case, Excel created 3 Workbook scope names for me, Alpha, Bravo and Charlie.

Working with Excel Shapes from C#

2006-06-21T09:33:00.000+09:30

In VBA, you can select shapes and control them usingSelection.ShapeRange. Selection morphs to different types depending on what property is called. Go here for more information.

In C#, the Selection(range) object does not have a ShapeRange property. However the DrawingObjects object does have aShapeRange property. So if you want to copy a ShapeRange from one sheet to another, try the following.

Say you have this VBA code to port to C#:

Set aShape = srcSheet.DrawingObjects.ShapeRange.Group
x = aShape.Left
y = aShape.Top
aShape.Copy
dstSheet.Paste
Selection.Left = x
Selection.Top = y
Selection.ShapeRange.Ungroup
aShape.Ungroup

This converts to:

aShape = (Excel.Shape)drawObj.ShapeRange.Group();
x = aShape.Left;
y = aShape.Top;
aShape.Copy();
dstSheet.Paste(Missing, Missing);
drawObj = (Excel.DrawingObjects)dstSheet.DrawingObjects(Missing);
Excel.ShapeRange shapeRng = (Excel.ShapeRange)drawObj.ShapeRange;
shapeRng.Left = (float)x;
shapeRng.Top = (float)y;
shapeRng.Ungroup();
aShape.Ungroup();

This solution assumes that there was nothing on the destination sheet to begin with. (the line dstSheet.DrawingObjects refers to all the Drawing objects on the sheet)

Using RibbonX UI with Office 2007 from C# COM Addin

2006-06-02T14:31:00.000+09:30

Hi all,

Yes, I am here still. I have been trying to use the RibbonX control in Office 2007 from a C# COM Addin. There is only one other blog that I have seen that has touched on the subject so far http://pschmid.net , so I look forward to seeing what he has to say in the coming weeks.

Any other blogs out there covering this subject?

Garbage Collection of CommandBarButtons

2005-12-18T09:00:00.000+10:30

I am building an Excel Addin in C#. It starts with creation of a single
commandbutton on the Excel toolbar (call it B1). When clicked this opens
a form with a few Pictureboxes. These pictureboxes can either be clicked
to start some routine or dragged onto the Excel toolbar to become a
commandbutton (call them B2). The commandbutton B2 has a clickhandler
event and has OnAction as . When I click the
pictureboxes on the Form, the form is made invisible. The pictureboxes
on the form fire ok, but after a series of events, the commandbutton
click events do not fire anymore.

e.g
1. open Excel, click a commandbutton previously dragged onto the Excel
toolbar (B2) - fires ok
2. click commandbutton on toolbar (B1) and click a pictureBox on Form -
fires ok
3. click (B2) - does not fire
4. click (B1) and click a pictureBox - fires ok

I should note that each time the commandbutton or picbox is clicked the
excel object is obtained from your method given in
http://blogs.officezealot.com/whitechapel/archive/2005/04/10.aspx

Andrew`Whitechapel: Second, the behavior you describe for the event handlers sounds exactly
like the classic delegate scoping issue. The object that holds the event
sink (delegate) must be declared at class scope, not at function scope.
If you declare it at function scope it will go out of scope at the end
of the function and become available for garbage collection. It will
then actually be garbage collected at some indeterminate point in the
future.

So, my advice is to use the Excel.Application object given to you up
front, and cache this at class scope. Then also cache the
CommandBarButton object at class scope.

Creating Excel Addin with C# Extensibility

2005-12-18T08:45:00.000+10:30

Well it has been a long time since my last.
I have been using C# over the last few months to automate an Excel Addin and have run into every gotcha known to man!
I will be compiling my experiences and hopefully they will be helpful to new Excel/Office Addin programmers.

Creating Long SQL strings with Arrays

2005-06-28T06:32:00.000+09:30

If you've ever created an long SQL string for a Pivot Table or some other reason, you will have come across Excel's limitations in this area. For example, you cannot have too many line continuations ( _ ). Also, if you have used the macro recorder while getting External Data through MS Query, there is some limitation there too. It will not actually record all the SQL, but cuts it off half way through.

The way the recorder works when getting data for a Pivot Table is interesting and I thought I'd use it in my code in a different way. It creates an array of arrays like this:

Sub Macro1()
'
' Macro1 Macro
' Macro recorded 28/06/2005 by A
'

'
    With ActiveWorkbook.PivotCaches.Add(SourceType:=xlExternal)
        .Connection = Array(Array( _
        "ODBC;DSN=Xtreme Sample Database 2003;DBQ=C:\Program Files\Microsoft Visual Studio .NET 2003\Crystal Reports\Samples\Database\xtreme." _
        ), Array("mdb;DriverId=25;FIL=MS Access;MaxBufferSize=2048;PageTimeout=5;"))
        .CommandType = xlCmdSql
        .CommandText = Array( _
        "SELECT Employee.`Employee ID`, Employee.`Supervisor ID`, Employee.`Last Name`, Employee.`First Name`, Employee.Position, Employee.`Birth Date`, Employee.`Hire Date`, Employee.`Home Phone`, Employee.Ex" _
        , _
        "tension, Employee.Photo, Employee.Notes, Employee.`Reports To`, Employee.Salary, Employee.SSN, Employee.`Emergency Contact First Name`, Employee.`Emergency Contact Last Name`, Employee.`Emergency Cont" _
        , _
        "act Relationship`, Employee.`Emergency Contact Phone`" & Chr(13) & "" & Chr(10) & "FROM Employee Employee" _
        )
        .CreatePivotTable TableDestination:="[Book1]Sheet1!R3C1", TableName:= _
        "PivotTable1", DefaultVersion:=xlPivotTableVersion10
    End With

    'do stuff with pivot tables

End Sub

It's a bit messy so I thought I'd clean it up. I used the array idea by adding bits of the string into the next element of a growing array, and then joining the array using the Join Function (opposite of Split).

Sub Macro1Redo()

    Dim ssql As String
    Dim sConn As String

    'create the array string
    Call AddToArray(ssql, "SELECT Employee.Employee ID, Employee.Supervisor ID, Employee.Last Name,")
    Call AddToArray(ssql, "Employee.First Name, Employee.Position, Employee.Birth Date, ")
    Call AddToArray(ssql, "Employee.Hire Date,Employee.Home Phone, Employee.Extension,")
    Call AddToArray(ssql, "Employee.Photo, Employee.Notes, Employee.Reports To,")
    Call AddToArray(ssql, "Employee.Salary, Employee.SSN, Employee.Emergency Contact First Name,")
    Call AddToArray(ssql, "Employee.Emergency Contact Last Name, Employee.Emergency Contact Relationship,")
    Call AddToArray(ssql, "Employee.Emergency Contact Phone ")
    Call AddToArray(ssql, "FROM Employee")

    'join the strings back together
    ssql = Join(ssql)

    Call AddToArray(sConn, "ODBC;DSN=Xtreme Sample Database 2003;")
    Call AddToArray(sConn, "DBQ=C:\Program Files\Microsoft Visual Studio .NET 2003\")
    Call AddToArray(sConn, "Crystal Reports\Samples\Database\xtreme.mdb;")
    Call AddToArray(sConn, "DriverId=25;FIL=MS Access;MaxBufferSize=2048;PageTimeout=5;")

    'join the strings back together
    sConn = Join(sConn)

    With ActiveWorkbook.PivotCaches.Add(SourceType:=xlExternal)
        .Connection = sConn
        .CommandType = xlCmdSql
        .CommandText = ssql
        .CreatePivotTable TableDestination:="[Book1]Sheet1!R3C1", TableName:= _
        "PivotTable1", DefaultVersion:=xlPivotTableVersion10
    End With

    'do stuff with pivot tables

End Sub

Sub AddToArray(myArray As Variant, arrayElement As Variant)

If Not IsArrayInitialized(myArray) Then
    ReDim myArray(0)
    myArray(0) = arrayElement
Else
    ReDim Preserve myArray(UBound(myArray) + 1)
    myArray(UBound(myArray)) = arrayElement
End If

End Sub

Using Randomization in Battleship Game

2005-06-16T09:52:00.000+09:30

There are a set of challenges at http://www.xl-logic.com/pages/challenge.html and I thought I'd give the Battleship Challenge a go. It involves the use of random numbers to fill a Battleship board without the ships falling off the board or overlapping each other. I used colours to represent the ships. There was an extra challenge to use shapes for the ships. I tried this out, but could not get the vertical ships to line up correctly. The cell.top and .left and shape.top and .left properties seem to be out of sync when you rotate an auto shape by 90 degress. Maybe someone has a solution? You can download the workbook here.

Removing Broken References and Adding VBA References

2005-06-09T09:04:00.000+09:30

A user had a question about my Controlling Outlook From Excel post.

I have been reading your homepage and I have a problem with my macro. It works
fine when the Microsoft Outlook Object Library is checked as reference.
But my file is to be executed on 67 different PCs and they have not (many of them)
any reference marked to Outlook. And if the reference to outlook is not marked
in advance, then the macro doesn’t run – but displays a compile error.

I have tried this with both Early and Late Binding.

Do you know a method where the macro by itself find the outlook version and automatically set the references?

I had the same problem, as I take a workbook of mine home and there are different versions of Outlook. When I returned to work, there was always a broken reference to Outlook 11 (2003).

The following code runs fine on my machine but I do not have any broken references at the moment. Note that the Auto_Open routine along with the rest of the code needs to be in a standard module. Auto_Open runs before the Workbook_Open event. Thanks to a comment from Rob van Gelder for the major and minor version code.

Note that there needs to be a reference to “Microsoft Visual Basic for Applications Extensibility 5.3? for this code to work.

Sub Auto_Open()

Call RemoveOutlookReferences
Call LoadOutlookReferences

End Sub

Sub LoadOutlookReferences()

'load Outlook object library
On Error Resume Next
'When using AddFromGUID, you can use zero for the major
'and minor versions to pick the latest.

'adding VBE object library:
ActiveWorkbook.VBProject.References.AddFromGuid _
"{0002E157-0000-0000-C000-000000000046}", 0, 0
'Adding outlook object library:
Application.VBE.ActiveVBProject.References _
.AddFromGuid "{00062FFF-0000-0000-C000-000000000046}", 0, 0
On Error GoTo 0

End Sub

Function ReferenceIsBroken(sRef As String) As Boolean

Dim vbProj As VBProject ' This refers to your VBA project.
Dim chkRef As Reference ' A reference.

' Refer to the VBA project.
Set vbProj = ThisWorkbook.VBProject

' Check through the selected references in the References dialog box.
For Each chkRef In vbProj.References

If sRef = chkRef.Name And chkRef.IsBroken Then

'if the ref matches the found ref and it is broken
ReferenceIsBroken = True
Exit Function

End If

Next

ReferenceIsBroken = False

End Function

Sub RemoveOutlookReferences()

Dim liCnt As Integer
Dim sRef As String
Dim count
Dim sThisVBEName As String
Const OUTLOOK_REF As String = "OUTLOO"

sThisVBEName = ThisWorkbook.VBProject.Name

'' Remove references to Outlook if they are there and are broken
For liCnt = Application.VBE.VBProjects.Item(sThisVBEName).References.count To 1 Step -1
sRef = UCase(Left(Application.VBE.VBProjects.Item(sThisVBEName).References.Item(liCnt).Name, 6))

Debug.Print sRef

If sRef = OUTLOOK_REF And ReferenceIsBroken(sRef) Then

Application.VBE.VBProjects.Item(sThisVBEName).References.Remove Application.VBE.VBProjects.Item(sThisVBEName).References.Item(liCnt)

End If
Next liCnt

End Sub

Updated FaceIDs program

2005-06-08T09:59:00.000+09:30

Some time ago, John Walkenbach at JWalk came up with an addin to show FaceIDs and their Control IDs.

Check out http://www.j-walk.com/ss/excel/tips/tip67.htm to see his version.

Incidentally, he said that I can do whatever I like with it because his PUP add-in has a MUCH better tool for identifying FaceIDs.

I have been using the original FaceID xla a fair bit in my work and have adapted it slightly. The reason I changed it is because most of the time, the FaceIDs are invalid for use on the menu, and I wanted to be able to see this when browsing the UserForm. Whenever the FaceID is invalid, the FaceID number will be black instead of the normal yellow. Download my version here.

Email me if you want a version for Excel 2003.

Check out the JWalk's site for install instructions.

Automatic Mouse Movement on UserForms

2005-06-06T15:03:00.000+09:30

I have been using an Excel addin which I had need to automate some
procedures overnight. There are a number a userforms which
have certain commandbuttons to click. Unfortunately, you cannot
access the Command Button click event from external code.

So I searched far and wide for a solution. I found the MouseMove API
routine and adapted it for VBA Userforms.

The principle is that you obtain and enter the dimensions of the UserForm
and Control that you want to access, and then the mouse moves
by itself to that location after a predetermined delay.

Here is a sample file to download if you wish to try it. Open the workbook, click the Start command button and a UserForm is shown. The mouse will click the command UserForm's button automatically.

Controlling Outlook from Excel

2005-06-02T16:03:00.000+09:30

I needed to be able to email a sheet or a workbook to Outlook after
running some code on the sheet to strip the code, formulas etc. The
built in Excel Send To dialog just send the workbook or sheet as is.
I have attached the code for controlling outlook. all you need to do is
manipulate your workbook and set the wbname variable to be your
Workbook name.

To send one sheet only, copy your sheet to another
workbook first and delete the default sheets.



Sub MailToOutlook()
'notes:
'You need a reference to the Outlook library by
'going to Tools > References and finding
'the outlook library
'if you open this with a computer with outlook 2003
', the reference will change
'to Outlook 11 library, compared to Outlook 2000
'which will refer an outlook 9 library


wbname = ThisWorkbook.FullName

Dim objol As New Outlook.Application
Dim objmail As MailItem
Set objol = New Outlook.Application
Set objmail = objol.createitem(olmailitem)

    With objmail
        'enter email address
        .To = "andrew@excelthoughts.com"
        '.cc = "whoever" 'enter e email address
        .Subject = "Email"
        .Body = "Please find the attached file"
        .NoAging = True
        'adds attachment to email
        .Attachments.Add wbname
        .display
    End With
  
    'destroy objects
    Set objmail = Nothing
    Set objol = Nothing
  
End Sub

Find Text in Hidden Cells

2005-06-01T11:00:00.000+09:30

Hi! This is my first ever post, so bear with me as I find my feet.

Excel's Find functionality is getting better as they release new versions, but there is still nothing that will allow you to search through hidden cells for text. I have included a snapshot of code that adds this functionality to the Find function.

To use it, copy the code into a module and type "FindThis" onto a sheet, hide the row or column and run the FindhiddenText routine. This code can be customised quite a lot e.g. Find All, Find on Multiple sheets etc.

Option Explicit

Public Function AdvancedFind(rToSearch As Range, _
sToFind As String) As Range

Dim rFound As Range
Dim rHiddenCols As Range
Dim rHiddenRows As Range

'unhide cols/rows
Set rHiddenCols = UnHideColumns(rToSearch)
Set rHiddenRows = UnHideRows(rToSearch)

Set rFound = rToSearch.Find(what:=sToFind)

'hide cols/rows
Call HideRowsAndColumns(rHiddenCols, rHiddenRows)

Set AdvancedFind = rFound

End Function

Sub HideRowsAndColumns(rHiddenCols As Range, _
rHiddenRows As Range)

Dim r As Range

    If Not rHiddenCols Is Nothing Then
        For Each r In rHiddenCols.Columns
            r.Columns.Hidden = True
        Next r
    End If

    If Not rHiddenRows Is Nothing Then
        rHiddenRows.Rows.Hidden = True
    End If


End Sub

Sub FindHiddenText()

Dim r As Range
Dim text As String

text = "FindThis"

Set r = AdvancedFind(ActiveSheet.Cells, text)

'display message
If Not r Is Nothing Then
    MsgBox "Found " & text & " at " & r.Address
Else
    MsgBox text & " not found"
End If

End Sub

Function UnHideColumns(rToSearch As Range) As Range

'''''''''''''''''''''
Dim c As Range
Dim rHiddenCols As Range

Set rHiddenCols = Nothing

For Each c In rToSearch.Columns
    If c.Hidden = True Then
        'unhide col
        c.Hidden = False

        'add to union range
        If rHiddenCols Is Nothing Then
            Set rHiddenCols = c
        Else
            Set rHiddenCols = Union(rHiddenCols, c)
        End If
    End If
Next c

Set UnHideColumns = rHiddenCols

End Function

Function UnHideRows(rToSearch As Range) As Range

'''''''''''''''''''''
Dim c As Range
Dim rHiddenRows As Range

Set rHiddenRows = Nothing

For Each c In rToSearch.Rows
    If c.Hidden = True Then
        'unhide col

        'add to union range
        If rHiddenRows Is Nothing Then
            Set rHiddenRows = c
        Else
            Set rHiddenRows = Union(rHiddenRows, c)
        End If


    End If
Next c

If Not rHiddenRows Is Nothing Then
    rHiddenRows.Rows.Hidden = False
End If

Set UnHideRows = rHiddenRows

End Function